nixfiles/hosts/hetzner-arm/containers/postgresql/profiles/restic.nix

{
  pkgs,
  config,
  ...
}: let
  secrets = config.services.secrets.secrets;

  backupPrepareCommand = "${
    (pkgs.writeShellScriptBin "backupPrepareCommand" ''
      systemctl start postgresqlBackup-piped --wait
      systemctl start postgresqlBackup-gotosocial --wait
      systemctl start postgresqlBackup-quassel --wait
      systemctl start postgresqlBackup-roundcube --wait
    '')
  }/bin/backupPrepareCommand";
in {
  environment.systemPackages = with pkgs; [
    restic
    (pkgs.writeShellScriptBin "restic-postgresql" ''
      env \
        RESTIC_PASSWORD_FILE=${secrets.restic_password.path} \
        $(cat ${secrets.restic_env.path}) \
      ${pkgs.restic}/bin/restic $@
    '')
  ];

  services.restic.backups.postgresql = {
    user = "root";
    paths = [
      "/var/backup/postgresql"
    ];

    # repository is overrided in environmentFile to contain auth
    # make sure to keep up to date when changing repository
    repository = "rest:https://storage-restic.owo.monster/PostgreSQL";
    passwordFile = "${secrets.restic_password.path}";
    environmentFile = "${secrets.restic_env.path}";

    pruneOpts = [
      "--keep-last 5"
    ];

    timerConfig = {
      OnBootSec = "1m";
      OnCalendar = "daily";
    };

    inherit backupPrepareCommand;
  };

  services.postgresqlBackup = {
    enable = true;
    backupAll = false;
    databases = [
      "piped"
      "gotosocial"
      "quassel"
      "roundcube"
    ];
    compression = "zstd";
  };
}