nixfiles/hosts/hetzner-arm/containers/quassel/profiles/restic.nix

{
  self,
  pkgs,
  config,
  ...
}: let
  backupSchedules = import "${self}/data/backupSchedules.nix";
  inherit (config.services.secrets) secrets;
in {
  environment.systemPackages = with pkgs; [
    restic
    (pkgs.writeShellScriptBin "restic-quassel" ''
      env \
        RESTIC_PASSWORD_FILE=${secrets.restic_password.path} \
        $(cat ${secrets.restic_env.path}) \
      ${pkgs.restic}/bin/restic $@
    '')
  ];

  services.restic.backups.quassel = {
    user = "root";
    paths = [
      # it's only backing up initial setup / credentials
      # so no matter what DB is restored to it should work
      "/home/quassel/.config/quassel-irc.org"
    ];

    # repository is overrided in environmentFile to contain auth
    # make sure to keep up to date when changing repository
    repository = "rest:https://storage-restic.owo.monster/Quassel";
    passwordFile = "${secrets.restic_password.path}";
    environmentFile = "${secrets.restic_env.path}";

    pruneOpts = ["--keep-last 5"];
    timerConfig = backupSchedules.restic.low;
  };
}