final: prev: rec {
  comic-sans = final.callPackage ./comic-sans {};
  comic-code = final.callPackage ./comic-code {};

  gobar = final.callPackage ./gobar {};

  mk-enc-usb = final.callPackage ../extras/mk-enc-usb.nix {};
  mk-encrypted-drive = final.callPackage ../extras/mk-encrypted-drive.nix {};
  mk-raspberry-ext-drive = final.callPackage ../extras/mk-raspberry-ext-drive.nix {};

  kitty-terminfo = final.runCommand "kitty-terminfo" {} ''
    mkdir -p $out/share
    cp -r ${./kitty-terminfo}/* $out/share
  '';

  # Remove when fixed in upstream
  jellyfin-ffmpeg =
    (prev.ffmpeg_6-headless.override {
      withAribcaption = false; # FIXME remove when updating past version 6.1
    })
    .overrideAttrs (old: rec {
      pname = "jellyfin-ffmpeg";
      version = "6.0.1-1";

      src = final.fetchFromGitHub {
        owner = "jellyfin";
        repo = "jellyfin-ffmpeg";
        rev = "v${version}";
        hash = "sha256-LMwGxx++z6TpZLnpeRGraid4653Mp8T4pY5EP4Z7GXY=";
      };

      patches = [];

      buildInputs = old.buildInputs ++ [prev.chromaprint];

      configureFlags =
        old.configureFlags
        ++ [
          "--extra-version=Jellyfin"
          "--disable-ptx-compression" # https://github.com/jellyfin/jellyfin/issues/7944#issuecomment-1156880067
          "--enable-chromaprint"
        ];

      postPatch = ''
        for file in $(cat debian/patches/series); do
          patch -p1 < debian/patches/$file
        done

        ${old.postPatch or ""}
      '';

      meta = with final.lib; {
        description = "${old.meta.description} (Jellyfin fork)";
        homepage = "https://github.com/jellyfin/jellyfin-ffmpeg";
        license = licenses.gpl3;
        maintainers = with maintainers; [justinas];
        pkgConfigModules = ["libavutil"];
      };
    });

  mpd-headless =
    (prev.mpdWithFeatures.override {
      ffmpeg = final.ffmpeg_6-headless;
    }) {
      features = [
        "audiofile"
        "ffmpeg"
        "faad"
        "flac"
        "mpg123"
        "opus"
        "vorbis"
        "vorbisenc"
        "lame"
        "libsamplerate"
        "libmpdclient"
        "id3tag"
        "expat"
        "pcre"
        "yajl"
        "icu"
        "sqlite"
        "systemd"
        "syslog"
        "io_uring"
      ];
    };

  owncast =
    (prev.owncast.override {
      ffmpeg = final.ffmpeg_6-headless;
    })
    .overrideAttrs (_old: {doCheck = false;});

  gotosocial = prev.gotosocial.overrideAttrs (_old: let
    owner = "superseriousbusiness";
    repo = "gotosocial";

    version = "0.13.2";
    source-hash = "sha256-VQnE4Xff4gtjQ6V2B42zK8UjosBWEMgcL/3Q8S0wc5Q=";
    web-assets-hash = "sha256-Iyqn0/VyigmOhlyyz1NfvNIXmWtF617QbWzM2c7jHWw=";

    web-assets = final.fetchurl {
      url = "https://github.com/${owner}/${repo}/releases/download/v${version}/${repo}_${version}_web-assets.tar.gz";
      hash = web-assets-hash;
    };
  in {
    inherit version;

    src = final.fetchFromGitHub {
      inherit owner repo;
      rev = "refs/tags/v${version}";
      hash = source-hash;
    };

    passthru.web-assets = web-assets;

    ldflags = ["-s" "-w" "-X main.Version=${version}"];

    doCheck = false;

    postInstall = ''
      tar xf ${web-assets}
      mkdir -p $out/share/gotosocial
      mv web $out/share/gotosocial/
    '';
  });
}