{
  tree,
  lib,
  inputs,
  config,
  ...
}: let
  container-addresses = import ../../data/container-addresses.nix {};
  hostIP = container-addresses.host;
  containerIP = container-addresses.containers.quassel;

  # Using secrets from Host
  secrets = config.services.secrets.secrets;
  secrets_list = [
    "quassel_restic_env"
    "quassel_restic_password"
  ];
in {
  networking.nat.forwardPorts = [
    {
      sourcePort = 4242;
      destination = "${containerIP}\:4242";
    }
  ];

  containers.quassel = {
    autoStart = true;
    privateNetwork = true;
    hostAddress = hostIP;
    localAddress = containerIP;
    bindMounts = lib.mkMerge (lib.forEach secrets_list (secret_name: let
      path = "${secrets.${secret_name}.path}";
    in {
      "${path}" = {
        hostPath = "${path}";
      };
    }));

    config = {
      config,
      pkgs,
      ...
    }: {
      _module.args = {
        inherit inputs;
        inherit tree;
        host_secrets = secrets;
      };

      imports = with tree;
        [
          profiles.base
          inputs.home-manager-unstable.nixosModules.home-manager

          profiles.sshd

          modules.nixos.secrets

          users.root
        ]
        ++ (with hosts.hetzner-vm.containers.quassel; [
          profiles.quassel
          profiles.restic
        ]);

      # For Shared Secrets
      systemd.tmpfiles.rules = [
        "d ${config.services.secrets.secretsDir} - root root"
      ];

      networking.firewall = {
        enable = true;
        allowedTCPPorts = [22 4242];
      };

      home-manager.users.root = {
        imports = with tree; [home.base home.dev.small];

        home.stateVersion = "23.05";
      };

      # Manually configure nameserver. Using resolved inside the container seems to fail
      # currently
      environment.etc."resolv.conf".text = "nameserver 8.8.8.8";
      system.stateVersion = "23.05";
    };
  };

  networking.firewall.allowedTCPPorts = [4242];
}