{self, ...} @ inputs: let
  nixpkgs = inputs.nixpkgs-unstable;
  lib = nixpkgs.lib;

  hosts = import ./hosts inputs;
in
  {
    nixosConfigurations = hosts.nixosConfigurations;
    #darwinConfigurations = hosts.darswinConfigurations;

    deploy.nodes = import ./deployNodes.nix {
      nixosConfigurations = self.nixosConfigurations;
      deploy-rs = inputs.deploy-rs;
    };
  }
  // (inputs.flake-utils.lib.eachDefaultSystem (system: let
    pkgs = import nixpkgs {
      inherit system;
      overlays = [
        (import ./overlay)
      ];
    };
  in {
    devShell = pkgs.mkShell {
      VAULT_API_ADDR = "https://vault.owo.monster";
      packages =
        (with pkgs; [
          git
          nano
          bat
          exa
          #inputs.deploy-rs.packages."x86_64-linux".deploy-rs
          (pkgs.callPackage ./extras/mk-enc-usb.nix {})
          (pkgs.callPackage ./extras/mk-normal-enc-ssd.nix {})
        ])
        ++ (with self.packages."${system}"; [
          mk-enc-usb
          mk-normal-enc-ssd
        ]);
    };

    apps = let
      packages = self.packages."${system}";
    in {
      mk-enc-usb = {
        type = "app";
        program = "${packages.mk-enc-usb}/bin/mk-enc-usb";
      };
      mk-normal-enc-ssd = {
        type = "app";
        program = "${packages.mk-normal-enc-ssd}/bin/mk-normal-enc-ssd";
      };
    };

    packages = {
      inherit (pkgs) comic-code comic-sans;
      inherit (pkgs) piped-frontend piped-backend piped-proxy;
      inherit (pkgs) mk-enc-usb mk-normal-enc-ssd;
    };
  }))